Added config file for csh/tcsh. It is based on the 'bash_profile' file,
but with several differences:
* Default ONOS_ROOT value is $HOME/onos instead of $HOME/onos-next
* Convenience utility functions and aliases are not included
* $MAVEN/bin is not included in the executable path
* The 'cell' funcion from BASH is renamed to 'onos-setup-cell'
Also, 'onos-setup-cell' always requires an argument: the cell name
Displaying the current cell setup can be done by the
'onos-show-cell' script
diff --git a/tools/dev/onos.cshrc b/tools/dev/onos.cshrc
new file mode 100644
index 0000000..8dba4b2
--- /dev/null
+++ b/tools/dev/onos.cshrc
@@ -0,0 +1,36 @@
+#!/bin/tcsh
+# ONOS developer csh/tcsh profile conveniences
+# Simply include in your own $HOME/.cshrc file. E.g.:
+#
+# setenv ONOS_ROOT $HOME/onos
+# if ( -f $ONOS_ROOT/tools/dev/onos.cshrc ) then
+# source $ONOS_ROOT/tools/dev/onos.cshrc
+# endif
+#
+
+# Root of the ONOS source tree
+if ( ! $?ONOS_ROOT ) then
+ setenv ONOS_ROOT $HOME/onos
+endif
+
+# Setup some environmental context for developers
+if ( ! $?JAVA_HOME ) then
+ if ( -x /usr/libexec/java_home ) then
+ setenv JAVA_HOME `/usr/libexec/java_home -v 1.7`
+ else if ( -d /usr/lib/jvm/java-7-openjdk-amd64 ) then
+ setenv JAVA_HOME /usr/lib/jvm/java-7-openjdk-amd64
+ endif
+endif
+if ( ! $?MAVEN ) then
+ setenv MAVEN $HOME/Applications/apache-maven-3.2.2
+endif
+if ( ! $?KARAF ) then
+ setenv KARAF $HOME/Applications/apache-karaf-3.0.1
+endif
+setenv KARAF_LOG $KARAF/data/log/karaf.log
+
+alias onos-setup-cell ' ( $ONOS_ROOT/tools/test/bin/onos-show-cell \!^ ) && setenv ONOS_CELL \!^'
+
+set path=( $path $ONOS_ROOT/tools/dev/bin $ONOS_ROOT/tools/test/bin )
+set path=( $path $ONOS_ROOT/tools/build )
+set path=( $path $KARAF/bin )